Geekly articles weekly

Control de aire acondicionado Haier basado en ESP8266

En la continuaciĂłn de los artĂ­culos sobre la construcciĂłn de una "casa inteligente" ... el



aire acondicionado de la serie Haier Lightera tiene en su tablero un módulo WiFi para controlarlo a través de una aplicación en el teléfono que funciona a través de un servicio en la nube chino desconocido. Para los modelos más antiguos, el módulo era una opción y se adquirió por separado; está conectado a la placa de control en la unidad interior. En los modelos nuevos, el conector está debajo de un borde decorativo y en la serie Lightera el módulo ya está instalado. Por lo tanto, esta unidad es aplicable a muchos aires acondicionados de la marca Haier.

Para controlar el aire acondicionado a través del módulo WiFi nativo, debe descargar la aplicación en su teléfono inteligente / tableta, registrarse, conectar su teléfono inteligente / tableta al enrutador a través de Wi-Fi. Encienda el aire acondicionado en modo de enfriamiento en 30 grados con una velocidad mínima del ventilador, asegúrese de que haya aparecido la red Haier-uAC e inicie el programa para buscar dispositivos y redes. El programa encuentra su aire acondicionado y las redes disponibles. Registre su red seleccionándola de la lista y proceda a registrar su modelo de equipo (aire acondicionado). En mi red doméstica, el servidor DHCP está deshabilitado en el enrutador y para conectarse a mi red WiFi en el dispositivo conectado, debe crear una nueva conexión y registrarse allí además del SSID (ya que está oculto) y la contraseña también tiene una dirección IP estática.Es por esta razón que no pude agregar mi aire acondicionado a la aplicación, ya que cuando agrego un aire acondicionado me pide que seleccione solo el punto de acceso WiFi y la contraseña. La aplicación envía los datos ingresados ​​al módulo WiFi del aire acondicionado y, utilizando estos datos, intenta conectarse a su punto de acceso, con la esperanza de que se le dé una dirección IP, pero mi enrutador rompe todas sus esperanzas.

Apariencia del mĂłdulo WiFi nativo.

Apariencia del mĂłdulo WiFi Haier nativo


Para la prueba, todavía lo conecté a través de otro enrutador. La administración a través de la aplicación funciona, pero no hay forma de controlar el aire acondicionado sin la aplicación, a través de la cual el servicio en la nube no está claro, no hay una cuenta personal. Como resultado, Haier, como muchos fabricantes de equipos, creó su propio hardware con su aplicación sin la posibilidad de integración con otros sistemas de automatización (sin módulos y equipos especiales). Al final, decidí hacer mi módulo WiFi con todas las características de un personaje conocido.

La base se tomó ESP8266 12F, que funcionará directamente con mi servidor utilizando el protocolo MQTT. IOBroker está instalado en el servidor , que también actúa como un servidor MQTT.

Quedaba por entender el protocolo de intercambio con el propio aire acondicionado. Después de estudiar el módulo nativo y los circuitos de la unidad de control de modelos anteriores, quedó claro que el módulo WiFi se comunica con el aire acondicionado a través de un UART regular con niveles TTL. Después de haber conectado el adaptador UART / USB en paralelo con la línea RX / TX y controlar el aire acondicionado desde la aplicación y el control remoto, leí todos los datos.

Foto placa base placa base.

Haier Native WiFi Module Board


La placa muestra un convertidor de 3.3 V CC / CC y convertidores de nivel lĂłgico. La pantalla no comenzĂł a disparar, lo que se desconoce debajo de ella.

Haier Native WiFi Module Board


Esta es mi primera experiencia con la reversiĂłn del protocolo, pero en mi opiniĂłn, el protocolo resultĂł ser muy simple.
El tipo de cambio es 9600/8-N-1. El módulo WiFi envía una solicitud cada 13 segundos (13 bytes), a la cual el aire acondicionado emite un paquete (37 bytes) con todos los datos. Debajo del spoiler, una lista de bytes que resultó ser desentrañada.

Protocolo de intercambio
1 — FF c
2 — FF c
3 — 22
4 — 00
5 — 00
6 — 00
7 — 00
8 — 00
9 — 01
10 — 01 — , 02 —
11 — 4D — , 6D —
12 — 5F —
13 — 00
14 — 1A — 26 , 1B — 27,
15 — 00
16 — 00
17 — 00
18 — 00 — , 7F-
19 — 00
20 — 00
21 — 00
22 — 00
23 — 00
24 — 00 — smart, 01 — cool, 02 — heat, 03 — , 04 — DRY,
25 — 00
26 — 00 — max, 01 — mid, 02 — min, 03 — auto — FanSpeed
27 — 00
28 — 00 — ., 01 — . 02 — / . 03 —
29 — 00 — , 80 .
30 — 00 — power off, x1 — power on, (1x ) — ? x9 — QUIET
31 — 00
32 — 00 — fresh off, 01 — fresh on
33 — 00
34 — 00
35 — 00
36 — 00 — 16 , 01 — 17 0E — 30 .
37 — . .

Equipos cortos
FF FF 0A 00 00 00 00 00 01 01 4D 02 5B
FF FF 0A 00 00 00 00 00 01 01 4D 03 5C
FF FF 0A 00 00 00 00 00 01 03 00 00 0E
FF FF 0A 00 00 00 00 00 01 01 4D 01 5A

Por ejemplo, para configurar la temperatura, es necesario enviar:
FF FF 22 00 00 00 00 00 01 01 4D 5F 00 00 00 00 00 00 00 00 00 00 00 00 01 00 02 00 00 00 01 00 00 00 00 00 04 04 D8 - configurado a 20 grados.

Dibujamos el diagrama del circuito. El circuito está alimentado por 5 voltios desde el acondicionador de aire, y dado que el voltaje de suministro del ESP8266 es de 3.3 voltios, se instala el regulador lineal LM1117 (AMS1117) para el voltaje de salida correspondiente. Los convertidores de nivel lógico se ensamblan en los elementos R1, Q1, R3 y R2, R3 ya que el TXD RXD del módulo ESP8266 no es tolerante a 5 V. Para programar el ESP, los contactos U2 U3 deben cerrarse juntos.
Diagrama de circuito
Esquema


Criamos una placa de circuito impreso. El diseño de la placa se realiza para la instalación en la carcasa desde el módulo WiFi nativo.
Placa de circuito

Placa de circuito

En la foto de abajo, el tablero de prueba.

El código está escrito en un entorno Arduino. La versión actual está disponible en GitHub .
codigo
#include <ESP8266WiFi.h>
#include <PubSubClient.h>

const char* ssid = "...";
const char* password = "...";
const char* mqtt_server = "xx.xx.xx.xx"; // MQTT

IPAddress ip(xx,xx,xx,x); //IP 
IPAddress gateway(xx,xx,xx,xx); // 
IPAddress subnet(xx,xx,xx,xx); // 

WiFiClient espClient;
PubSubClient client(espClient);

#define ID_CONNECT "myhome-Conditioner"
#define LED     12
#define LEN_B   37

#define B_CUR_TMP   13  // 
#define B_CMD       17  // 00- 7F- ???
#define B_MODE      23  //04 - DRY, 01 - cool, 02 - heat, 00 - smart 03 - 
#define B_FAN_SPD   25  // 02 - min, 01 - mid, 00 - max, 03 - auto
#define B_SWING     27  //01 -     . 00 - . 02 - / . 03 -  
#define B_LOCK_REM  28  //80  . 00 -  
#define B_POWER     29  //on/off 01 - on, 00 - off (10, 11)-??? 09 - QUIET
#define B_FRESH     31  //fresh 00 - off, 01 - on
#define B_SET_TMP   35  // 

int fresh;
int power;
int swing;
int lock_rem;
int cur_tmp;
int set_tmp;
int fan_spd;
int Mode;
long prev = 0;
byte inCheck = 0;
byte qstn[] = {255,255,10,0,0,0,0,0,1,1,77,1,90}; //  
//byte start[] = {255,255};
byte data[37] = {}; // 
byte on[]   = {255,255,10,0,0,0,0,0,1,1,77,2,91}; //  
byte off[]  = {255,255,10,0,0,0,0,0,1,1,77,3,92}; //  
byte lock[] = {255,255,10,0,0,0,0,0,1,3,0,0,14};  //  
//byte buf[10];

void setup_wifi() {
  delay(10);
  WiFi.begin(ssid, password);
  WiFi.config(ip, gateway, subnet);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    digitalWrite(LED, !digitalRead(LED));
  }
  digitalWrite(LED, HIGH);
}

void reconnect() {
  digitalWrite(LED, !digitalRead(LED));
  while (!client.connected()) {
    if (client.connect(ID_CONNECT)) {
      client.publish("myhome/Conditioner/connection", "true");
      client.publish("myhome/Conditioner/RAW", "");
      client.subscribe("myhome/Conditioner/#");
      digitalWrite(LED, HIGH);
    } else {
      delay(5000);
    }
  }
}

void InsertData(byte data[], size_t size){
    set_tmp = data[B_SET_TMP]+16;
    cur_tmp = data[B_CUR_TMP];
    Mode = data[B_MODE];
    fan_spd = data[B_FAN_SPD];
    swing = data[B_SWING];
    power = data[B_POWER];
    lock_rem = data[B_LOCK_REM];
    fresh = data[B_FRESH];
  /////////////////////////////////
  if (fresh == 0x00){
      client.publish("myhome/Conditioner/Fresh", "off");
  }
  if (fresh == 0x01){
      client.publish("myhome/Conditioner/Fresh", "on");
  }
  /////////////////////////////////
  if (lock_rem == 0x80){
      client.publish("myhome/Conditioner/Lock_Remote", "true");
  }
  if (lock_rem == 0x00){
      client.publish("myhome/Conditioner/Lock_Remote", "false");
  }
  /////////////////////////////////
  if (power == 0x01 || power == 0x11){
      client.publish("myhome/Conditioner/Power", "on");
  }
  if (power == 0x00 || power == 0x10){
      client.publish("myhome/Conditioner/Power", "off");
  }
  if (power == 0x09){
      client.publish("myhome/Conditioner/Power", "quiet");
  }
  if (power == 0x11 || power == 0x10){
      client.publish("myhome/Conditioner/Compressor", "on");
  } else {
    client.publish("myhome/Conditioner/Compressor", "off");
  }
  /////////////////////////////////
  if (swing == 0x00){
      client.publish("myhome/Conditioner/Swing", "off");
  }
  if (swing == 0x01){
      client.publish("myhome/Conditioner/Swing", "ud");
  }
  if (swing == 0x02){
      client.publish("myhome/Conditioner/Swing", "lr");
  }
  if (swing == 0x03){
      client.publish("myhome/Conditioner/Swing", "all");
  }
  /////////////////////////////////  
  if (fan_spd == 0x00){
      client.publish("myhome/Conditioner/Fan_Speed", "max");
  }
  if (fan_spd == 0x01){
      client.publish("myhome/Conditioner/Fan_Speed", "mid");
  }
  if (fan_spd == 0x02){
      client.publish("myhome/Conditioner/Fan_Speed", "min");
  }
  if (fan_spd == 0x03){
      client.publish("myhome/Conditioner/Fan_Speed", "auto");
  }
  /////////////////////////////////
  char b[5]; 
  String char_set_tmp = String(set_tmp);
  char_set_tmp.toCharArray(b,5);
  client.publish("myhome/Conditioner/Set_Temp", b);
  ////////////////////////////////////
  String char_cur_tmp = String(cur_tmp);
  char_cur_tmp.toCharArray(b,5);
  client.publish("myhome/Conditioner/Current_Temp", b);
  ////////////////////////////////////
  if (Mode == 0x00){
      client.publish("myhome/Conditioner/Mode", "smart");
  }
  if (Mode == 0x01){
      client.publish("myhome/Conditioner/Mode", "cool");
  }
  if (Mode == 0x02){
      client.publish("myhome/Conditioner/Mode", "heat");
  }
  if (Mode == 0x03){
      client.publish("myhome/Conditioner/Mode", "vent");
  }
  if (Mode == 0x04){
      client.publish("myhome/Conditioner/Mode", "dry");
  }
  
  String raw_str;
  char raw[75];
  for (int i=0; i < 37; i++){
     if (data[i] < 10){
       raw_str += "0";
       raw_str += String(data[i], HEX);
     } else {
      raw_str += String(data[i], HEX);
     }    
  }
  raw_str.toUpperCase();
  raw_str.toCharArray(raw,75);
  client.publish("myhome/Conditioner/RAW", raw);
  
///////////////////////////////////
}

byte getCRC(byte req[], size_t size){
  byte crc = 0;
  for (int i=2; i < size; i++){
      crc += req[i];
  }
  return crc;
}

void SendData(byte req[], size_t size){
  //Serial.write(start, 2);
  Serial.write(req, size - 1);
  Serial.write(getCRC(req, size-1));
}

inline unsigned char toHex( char ch ){
   return ( ( ch >= 'A' ) ? ( ch - 'A' + 0xA ) : ( ch - '0' ) ) & 0x0F;
}

void callback(char* topic, byte* payload, unsigned int length) {
  payload[length] = '\0';
  String strTopic = String(topic);
  String strPayload = String((char*)payload);
  ///////////
  if (strTopic == "myhome/Conditioner/Set_Temp"){
    set_tmp = strPayload.toInt()-16;
    if (set_tmp >= 0 && set_tmp <= 30){
      data[B_SET_TMP] = set_tmp;      
    }
  }
  //////////
  if (strTopic == "myhome/Conditioner/Mode"){
     if (strPayload == "smart"){
      data[B_MODE] = 0; 
    }
    if (strPayload == "cool"){
        data[B_MODE] = 1;
    }
    if (strPayload == "heat"){
        data[B_MODE] = 2; 
    }
    if (strPayload == "vent"){
        data[B_MODE] = 3;
    }
    if (strPayload == "dry"){
        data[B_MODE] = 4;
    }
  }
  //////////
  if (strTopic == "myhome/Conditioner/Fan_Speed"){
     if (strPayload == "max"){
      data[B_FAN_SPD] = 0; 
    }
    if (strPayload == "mid"){
        data[B_FAN_SPD] = 1;
    }
    if (strPayload == "min"){
        data[B_FAN_SPD] = 2; 
    }
    if (strPayload == "auto"){
        data[B_FAN_SPD] = 3; 
    }
  }
  ////////
  if (strTopic == "myhome/Conditioner/Swing"){
     if (strPayload == "off"){
      data[B_SWING] = 0; 
    }
    if (strPayload == "ud"){
        data[B_SWING] = 1;
    }
    if (strPayload == "lr"){
        data[B_SWING] = 2; 
    }
    if (strPayload == "all"){
        data[B_SWING] = 3; 
    }
  }
  ////////
  if (strTopic == "myhome/Conditioner/Lock_Remote"){
     if (strPayload == "true"){
      data[B_LOCK_REM] = 80;
    }
    if (strPayload == "false"){
        data[B_LOCK_REM] = 0;
    }
  }
  ////////
  if (strTopic == "myhome/Conditioner/Power"){
     if (strPayload == "off" || strPayload == "false" || strPayload == "0"){
      SendData(off, sizeof(off)/sizeof(byte));
      return;
    }
    if (strPayload == "on" || strPayload == "true" || strPayload == "1"){
      SendData(on, sizeof(on)/sizeof(byte));
      return;
    }
    if (strPayload == "quiet"){
        data[B_POWER] = 9;
    }
  }
  ////////
  if (strTopic == "myhome/Conditioner/RAW"){
    char buf[75];
    char hexbyte[3] = {0};
    strPayload.toCharArray(buf, 75);
    int octets[sizeof(buf) / 2] ;
    for (int i=0; i < 76; i += 2){
      hexbyte[0] = buf[i] ;
      hexbyte[1] = buf[i+1] ;
      data[i/2] = (toHex(hexbyte[0]) << 4) | toHex(hexbyte[1]);
    }
    Serial.write(data, 37);
    client.publish("myhome/Conditioner/RAW", buf);
  }
  
  data[B_CMD] = 0;
  data[9] = 1;
  data[10] = 77;
  data[11] = 95;
  SendData(data, sizeof(data)/sizeof(byte));
}

void setup() {
  pinMode(LED, OUTPUT);
  Serial.begin(9600);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
}

void loop() {
  if(Serial.available() > 0){
    Serial.readBytes(data, 37);
    while(Serial.available()){
      delay(2);
      Serial.read();
    }
    if (data[36] != inCheck){
      inCheck = data[36];
      InsertData(data, 37);
    }
  }
  
  if (!client.connected()){
    reconnect();
  }
  client.loop();

  long now = millis();
  if (now - prev > 5000) {
    prev = now;
    SendData(qstn, sizeof(qstn)/sizeof(byte)); // 
  }
}


Después de flashear el ESP8266, colocamos el módulo en el aire acondicionado. Los temas se crean automáticamente en el servidor MQTT:
Placa de circuito


Panel de control de aire acondicionado en una página web.
Placa de circuito

Además de administrar desde una página web, se organiza la administración de comandos de voz, así como a través del controlador de Telegram para IOBroker.
A un costo, el nuevo mĂłdulo costĂł alrededor de 200 rublos.


La primera parte: hogar inteligente, el comienzo.
Segunda parte - Contador de visitantes del baño

Source: https://habr.com/ru/post/es395533/

More articles:


All Articles